Convert number to words as per currency ISO Code

In my earlier blog, we saw how to use the Spell Number with a single currency in the blog, this is a UDF (customized VBA Code) of Spell Number, where there is the second argument allow you to change currency type =Spellnumber(cellvalue,[CUR])

Get Access to Your File

Enter your name and email to receive access to the file.

You can use the code in Excel for mac & windows

Copy the below VBA Code by clicking on the copy box
Open Microsoft Visual Basic for Applications window Developer Ribbon Tab > Visual Basic (Shortcut keys as follows for mac & windows)
1. mac users fn +⌥ + F11
2. windows users Alt + F11
From the menu bar select Insert > Module and insert new Module
Paste the code into the module

'****************************************************************
'    Code Modified By : Faraz Shaikh | ExcelExciting.com
'    Dated            : 07.07.2019
'    Ver.             : 1.0
'****************************************************************
Option Explicit
'Main Function
Function SpellNumberCur(ByVal MyNumber, Curr)
Dim IntegerValue, DecimalValue, Temp, CurrDecimalValue, CurrIntegerValue, MyValue
Dim DecimalPlace, Count
ReDim Place(9) As String
Place(2) = " Thousand "
Place(3) = " Million "
Place(4) = " Billion "
Place(5) = " Trillion "
CurrDecimalValue = Curr
CurrIntegerValue = Curr
If IsEmpty(CurrDecimalValue) Then
    MsgBox "Enter Currency Type, 3 digit ISO ", vbCritical
Else
    Select Case CurrDecimalValue
        Case "USD"
        CurrDecimalValue = "Cent"
        Case "EUR"
        CurrDecimalValue = "Cent"
        Case "SAR"
        CurrDecimalValue = "Halala"
        Case "INR"
        CurrDecimalValue = "Paisa"
        Case "AED"
        CurrDecimalValue = "fil"
        Case Else
        CurrDecimalValue = "Cent"
    End Select
    Select Case CurrIntegerValue
        Case "USD"
        CurrIntegerValue = "Dollar"
        Case "EUR"
        CurrIntegerValue = "Euro"
        Case "SAR"
        CurrIntegerValue = "Riyal"
        Case "INR"
        CurrIntegerValue = "Rupee"
        Case "AED"
        CurrIntegerValue = "Dirham"
        Case Else
        CurrIntegerValue = "Dollor"
    End Select
End If
' String representation of amount.
    MyNumber = Round(Trim(Str(MyNumber)), 2) 'Rounded the value upto 2 decmial places
' Position of decimal place 0 if none.
    DecimalPlace = InStr(MyNumber, ".")
' Convert DecimalValue and set MyNumber to dollar amount.
    If DecimalPlace > 0 Then
        DecimalValue = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & "00", 2))
        MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
    End If
    Count = 1
    Do While MyNumber <> ""
        Temp = GetHundreds(Right(MyNumber, 3))
        If Temp <> "" Then IntegerValue = Temp & Place(Count) & IntegerValue
        If Len(MyNumber) > 3 Then
            MyNumber = Left(MyNumber, Len(MyNumber) - 3)
        Else
            MyNumber = ""
        End If
        Count = Count + 1
    Loop
    Select Case IntegerValue
        Case ""
        IntegerValue = "No " & CurrIntegerValue & "s"
        Case "One"
        IntegerValue = "One " & CurrIntegerValue & ""
        Case Else
        IntegerValue = IntegerValue & " " & CurrIntegerValue & "s"
    End Select
    Select Case DecimalValue
        Case ""
        DecimalValue = " and No " & CurrDecimalValue & "s"
        Case "One"
        DecimalValue = " and One " & CurrDecimalValue
        Case Else
        DecimalValue = " and " & DecimalValue & " " & CurrDecimalValue & "s"
    End Select
'Code Customized By Faraz Shaikh | fshaikh Excel Master
SpellNumberCur = IntegerValue & DecimalValue
End Function
' Converts a number from 100-999 into text
Function GetHundreds(ByVal MyNumber)
Dim Result As String
    If Val(MyNumber) = 0 Then Exit Function
        MyNumber = Right("000" & MyNumber, 3)
' Convert the hundreds place.
    If Mid(MyNumber, 1, 1) <> "0" Then
        Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
    End If
' Convert the tens and ones place.
    If Mid(MyNumber, 2, 1) <> "0" Then
        Result = Result & GetTens(Mid(MyNumber, 2))
    Else
        Result = Result & GetDigit(Mid(MyNumber, 3))
    End If
GetHundreds = Result
End Function
' Converts a number from 10 to 99 into text.
Function GetTens(TensText)
Dim Result As String
Result = "" ' Null out the temporary function value.
    If Val(Left(TensText, 1)) = 1 Then ' If value between 10-19...
        Select Case Val(TensText)
            Case 10: Result = "Ten"
            Case 11: Result = "Eleven"
            Case 12: Result = "Twelve"
            Case 13: Result = "Thirteen"
            Case 14: Result = "Fourteen"
            Case 15: Result = "Fifteen"
            Case 16: Result = "Sixteen"
            Case 17: Result = "Seventeen"
            Case 18: Result = "Eighteen"
            Case 19: Result = "Nineteen"
        Case Else
        End Select
    Else ' If value between 20-99...
        Select Case Val(Left(TensText, 1))
            Case 2: Result = "Twenty "
            Case 3: Result = "Thirty "
            Case 4: Result = "Forty "
            Case 5: Result = "Fifty "
            Case 6: Result = "Sixty "
            Case 7: Result = "Seventy "
            Case 8: Result = "Eighty "
            Case 9: Result = "Ninety "
        Case Else
        End Select
        Result = Result & GetDigit(Right(TensText, 1))  ' Retrieve ones place.
    End If
GetTens = Result
End Function
' Converts a number from 1 to 9 into text.
Function GetDigit(Digit)
Select Case Val(Digit)
    Case 1: GetDigit = "One"
    Case 2: GetDigit = "Two"
    Case 3: GetDigit = "Three"
    Case 4: GetDigit = "Four"
    Case 5: GetDigit = "Five"
    Case 6: GetDigit = "Six"
    Case 7: GetDigit = "Seven"
    Case 8: GetDigit = "Eight"
    Case 9: GetDigit = "Nine"
Case Else: GetDigit = ""
End Select
End Function

Was the information helpful in this blog?